supercollider

rot

clean-up #3:

beat rotation as described here...
http://music.columbia.edu/~douglas/strange_things/?p=78
implemented as a method for SequenceableCollection. some test code...

s.boot
(
SynthDef(\segMono, {|out= 0, buffer, amp= 0.5, rate= 1, offset= 0, atk= 0.01, rel= 0.1, gate= 1|
        var env= EnvGen.ar(Env.asr(atk, amp, rel), gate, doneAction:2);
        var src= PlayBuf.ar(1, buffer, rate*BufRateScale.ir(buffer), 1, offset*BufFrames.ir(buffer));
        OffsetOut.ar(out, Pan2.ar(src*env));
}).add;
SynthDef(\segStereo, {|out= 0, buffer, amp= 0.5, rate= 1, offset= 0, atk= 0.01, rel= 0.1, gate= 1|
        var env= EnvGen.ar(Env.asr(atk, amp, rel), gate, doneAction:2);
        var src= PlayBuf.ar(2, buffer, rate*BufRateScale.ir(buffer), 1, offset*BufFrames.ir(buffer));
        OffsetOut.ar(out, src*env);
}).add;
)
b= Buffer.read(s, "/Users/asdf/soundfiles/amen.wav")  //***edit to match***
b.numChannels           //use instrument \segStereo for 2 channel files and instrument \segMono for 1 channel files
~bpm= 60/(b.duration/16)      //calculate tempo in bpm. 16 is the number of beats in the file. ***edit to match***
c= TempoClock(~bpm/60);       //create a tempo clock in the tempo of the file
Pdef(\test).play(c, quant:1)
(       //rot example 1 - shuffle
Pdef(\test, Pbind(
        \instrument, \segStereo,  //***edit to match***
        \buffer, b,
        \dur, 1,
        \amp, 0.75,
        \offset, Pseq((0..15).rot(2, 1, 0, 4)/16, inf)
))
)
(       //rot example 2 - double tempo
Pdef(\test, Pbind(
        \instrument, \segStereo,
        \buffer, b,
        \dur, 0.5,
        \amp, 0.75,
        \offset, Pseq((0..15).rot(2, 1, 1, 4)/16, inf)
))
)
(       //rot example 3 - double and triple tempo
Pdef(\test, Pbind(
        \instrument, \segStereo,
        \buffer, b,
        \dur, Pseq([0.5, 0.25, 0.25], inf),
        \amp, 0.75,
        \offset, Pseq((0..15).rot(0, 1, 1, 8)/16, inf)
))
)
(       //rot example 4 - subdivide into 32 segments
Pdef(\test, Pbind(
        \instrument, \segStereo,
        \buffer, b,
        \dur, Pseq([0.5, 0.25, 0.25], inf),
        \amp, 0.75,
        \offset, Pseq((0..31).rot(1, 1, 1, 4)/32, inf)
))
)
(       //rot example 5 - back to original
Pdef(\test, Pbind(
        \instrument, \segStereo,
        \buffer, b,
        \dur, 1,
        \amp, 0.75,
        \offset, Pseq((0..15).rot(0, 0, 0, 4)/16, inf)
))
)
Pdef(\test).stop
b.free;

in the mp3 recording of the above code, each rotation example gets to play for 16 beats.


AttachmentSize
Package icon extSequenceableCollection-rot.sc_.zip924 bytes

pfork

clean-up #2:
another very old supercollider class i never got around to publish. it's called Pfork and makes it possible to blend or fade out patterns in other ways than plain [volume] crossfading. It was originally written for the installation Intelligent Street (in SC2) where it was used as a way of creating new music styles from a mix of multiple other styles.

here's one example of slowly zeroing out amplitudes in a 16 step pattern. frac is a value slowly changing from 1.0 to 0.0 and indicates how many values to zero out. the fork pattern is [3, 1, 2, 0]. this pattern decides which indices to zero out and in which order. so here index 3 is first in the fork pattern and will thereby be seen as the least important in the original pattern. all indices 3 will be zeroed out first. after that all indices 1 and so on. the last indices zeroed out (ie kept until frac is almost 0.0) are the indices 0 - ie the first beat out of 4 in the original amplitude step pattern.
this ascii printout should help visualise what is happening...

1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1         //frac is 1.0
1 1 1 0 1 1 1 1 1 1 1 1 1 1 1 1
1 1 1 0 1 1 1 0 1 1 1 1 1 1 1 1
1 1 1 0 1 1 1 0 1 1 1 0 1 1 1 1
1 1 1 0 1 1 1 0 1 1 1 0 1 1 1 0
1 0 1 0 1 1 1 0 1 1 1 0 1 1 1 0
1 0 1 0 1 0 1 0 1 0 1 0 1 1 1 0
1 0 1 0 1 0 1 0 1 0 1 0 1 0 1 0         //frac is 0.5
1 0 0 0 1 0 1 0 1 0 1 0 1 0 1 0
1 0 0 0 1 0 0 0 1 0 1 0 1 0 1 0
1 0 0 0 1 0 0 0 1 0 0 0 1 0 1 0
1 0 0 0 1 0 0 0 1 0 0 0 1 0 0 0
0 0 0 0 1 0 0 0 1 0 0 0 1 0 0 0
0 0 0 0 0 0 0 0 1 0 0 0 1 0 0 0
0 0 0 0 0 0 0 0 0 0 0 0 1 0 0 0
0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0         //frac is 0.0

one can also imagine 1 or 0 to be other things than amplitude and basically any array can fork into any other.
here's an example going slowly from one melodic pattern into another. (mp3 recording below)

//slowly fork from one pattern to another in the opposite channel
(
a= 0.2.dup(16); //amplitudes
f= [0, 2, 1, 3];        //forkpattern for left channel
g= [3, 1, 2, 0];        //forkpattern for right channel
Pbind(\pan, -1, \dur, 0.125, \degree, Pseq([5, 6, 7, 8], inf), \amp, Pfork(a, f, Pseries(1, -0.1, 11), 0, 11)).play;
Pbind(\pan, 1, \dur, 0.125, \degree, Pseq([3, 2, 1, 0], inf), \amp, Pfork(a, g, Pseries(0, 0.1, 11), 0, 11)).play;
)

see the helpfile for more examples.
i plan to (someday) write a Pfunc2 class that work in a similar way but inherits from FilterPattern instead of ListPattern.


update 180101: added new helpfile

AttachmentSize
Package icon Pfork.zip8.98 KB

bjorklund

clean-up #1:
two supercollider classes i wrote long ago (nov 2008) after a technique described by Godfried Toussaint in his paper 'The Euclidean Algorithm Generates Traditional Musical Rhythms' http://www-cgrl.cs.mcgill.ca/~godfried/publications/banff.pdf
also see http://ruinwesen.com/blog?id=216 for another implementation with some great demos. and Bjorn Westergard has a sc demo here.

lots of typical patterns in say techno music can be described like this using only two numbers (relation).

Bjorklund is now available as a supercollider quark. install it via the following commands...

Quarks.install("Bjorklund");
//and recompile

below is some example supercollider code with resulting output as mp3. the hihat plays a 9/16 rhythm throughout and the snare plays 3 different ones... 5/8, 15/16 and 3/8.

s.boot
a= Buffer.read(s, "sounds/Free_CR68/CR68_BD_B_03.wav")
b= Buffer.read(s, "sounds/Free_CR68/CR68_SD_B1.wav")
c= Buffer.read(s, "sounds/Free_CR68/CR68_hh_02.wav")

(
SynthDef(\oneshotMono, {|out= 0, amp= 0.1, pan= 0, rate= 1, buffer|
        var src= PlayBuf.ar(1, buffer, rate*BufRateScale.ir(buffer), doneAction:2);
        Out.ar(out, Pan2.ar(src, pan, amp));
}).add;
)

d= TempoClock(120/60)
Pdef(\bd).play(d, quant:4)
Pdef(\hh).play(d, quant:4)
Pdef(\sd).play(d, quant:4)
Pdef(\bd, Pbind(\instrument, \oneshotMono, \buffer, a, \dur, 1.00, \amp, 0.7))
Pdef(\hh, Pbind(\instrument, \oneshotMono, \buffer, c, \dur, 0.25, \amp, Pbjorklund(9, 16, inf)*0.7, \pan, Pbrown(-1, 1, 0.2, inf)))
Pdef(\sd, Pbind(\instrument, \oneshotMono, \buffer, b, \dur, 0.25, \amp, Pbjorklund(5, 8, inf)*0.3))
Pdef(\sd, Pbind(\instrument, \oneshotMono, \buffer, b, \dur, 0.25, \amp, Pbjorklund(15, 16, inf)*0.3))
Pdef(\sd, Pbind(\instrument, \oneshotMono, \buffer, b, \dur, 0.25, \amp, Pbjorklund(3, 8, inf)*0.3))
Pdef(\bd).stop
Pdef(\sd).stop
Pdef(\hh).stop


update 110316: adapted Pbjorklund to also take patterns as arguments.
update 110320: made a quark out of it

OpenObject tutorials

7 short screencasts with code examples showing how to connect supercollider with max/pd/processing (etc) using the openobject quark.
download the example code here... http://www.subnet.at/content/supercollider-tutorials-0

to run all the examples you will need supercollider, processing (with the oscP5 library), maxmsp and puredata.

install OpenObject from within supercollider with Quarks.install("OpenObject");

these screencasts were made at the 10days of SuperCollider network music workshop at subnet, salzburg, october 2009.

openobject quark by julian rohrhuber, tutorials by fredrik olofsson, voiceover and support by max kickinger.

thanks to subnet.at

OpenObject overview from redFrik on Vimeo.

OpenObject 00 maxmsp from redFrik on Vimeo.

OpenObject 01 maxmsp from redFrik on Vimeo.

OpenObject 02 maxmsp from redFrik on Vimeo.

OpenObject 03 puredata from redFrik on Vimeo.

OpenObject 04 puredata from redFrik on Vimeo.

OpenObject 05 processing from redFrik on Vimeo.

update 150316: uploaded the code here below and made it compatible with sc3.6. thanks to edN for noticing.
update 180101: updated the pd examples to use pd vanilla instead of pd extended

AttachmentSize
Package icon openobject_demos.zip36.77 KB

swiki

just a listing of some of the supercollider code i've published on the swiki. much is old but still fully functional and hopefully useful.

http://swiki.hfbk-hamburg.de:8888/MusicTechnology/743 - 3d extensions for the Pen class. vector and matrix multiplication.

http://swiki.hfbk-hamburg.de:8888/MusicTechnology/760 - 1d cellular automata pattern.

http://swiki.hfbk-hamburg.de:8888/MusicTechnology/818 - livecoding practice sessions.

http://swiki.hfbk-hamburg.de:8888/MusicTechnology/854 - more livecoding practice sessions.

http://swiki.hfbk-hamburg.de:8888/MusicTechnology/763 - tempo clock synchronisation and beat matching.

http://swiki.hfbk-hamburg.de:8888/MusicTechnology/833 - some drawings.

http://swiki.hfbk-hamburg.de:8888/MusicTechnology/901 - examples ported from nodebox.

http://swiki.hfbk-hamburg.de:8888/MusicTechnology/902 - examples ported from processing.

http://swiki.hfbk-hamburg.de:8888/MusicTechnology/726 - quicklauncher folder gui.

http://swiki.hfbk-hamburg.de:8888/MusicTechnology/810 - hacked server windows.

http://swiki.hfbk-hamburg.de:8888/MusicTechnology/870 - a silly drummachine.

http://swiki.hfbk-hamburg.de:8888/MusicTechnology/869 - port of particle chamber by derek holzer.

http://swiki.hfbk-hamburg.de:8888/MusicTechnology/906 - examples ported from form+code.

klipp av logo

some supercollider code to generate old school klipp av logos.

click the window in the sc code to generate new pictures.

//redFrik
(
        var width= 800, height= 600;
        var win, usr, p0, p1, l= 50, w= 10, h= 15, c= 0.9, o= 0.1;
        win= Window("nystan", Rect(128, 64, width, height), false);
        usr= UserView(win, Rect(0, 0, width, height));
        usr.mouseDownAction= {usr.refresh};
        usr.background= Color.new255(51, 47, 57);
        win.front;
        usr.drawFunc= {
                Pen.translate(width*0.5, height*0.5);
                5.rrand(20).do{
                        var p, pp1, len;
                        Pen.rotate(pi.linrand);
                        p0= Point(0, 0);
                        p1= Point(0, h.rand*10.linrand);
                        pp1= p1;
                        (20.linrand).do{|i|
                                len= l+l.rand2;
                                Pen.color= Color(c, c, c.rrand(1.0), (1-c).rrand(1.0));
                                Pen.moveTo(p0);
                                Pen.lineTo(p1);
                                if(o.coin, {
                                        p= 200.rand;
                                        p0= p0+p;
                                        p1= p1+p;
                                }, {
                                        p0= p0+Point(len+w.rand2, h.rand);
                                        p1= p1+Point(len+w.rand2, h.rand);
                                });
                                Pen.lineTo(p1);
                                Pen.lineTo(p0);
                                Pen.draw(0);
                        };
                        Pen.moveTo(p0);
                        Pen.lineTo(p1);
                        Pen.lineTo(pp1);
                        Pen.lineTo(Point(0, 0));
                        Pen.draw(5.rand);
                };
        };
        CmdPeriod.doOnce({if(win.isClosed.not, {win.close})});
)

sunday drawings

2006 i fiddled with some simple drawing routines in sc. (http://swiki.hfbk-hamburg.de:8888/MusicTechnology/833). now i've added matching (?) sound synthesis and some slight modifications to the drawing code. there are 7 parameters that are used to both generate the picture and the sound. normally the parameters are randomised but it is possible to copy&paste a good sounding/looking set of parameters into the code to get the same drawing back.

below is the new code + embedded vimeos.

//redFrik
(
s.latency= 0.05;
s.waitForBoot{
        var width= 640, height= 480, w, u, drawFunc, clearFunc;
        var fadeAtk= 1400, fadeSus= 700, fadeRel= 350;
        var a, b, c, d, e, f, g, i= 0, theta= 0;
        var syn= SynthDef(\sunday, {|amp= 0, a= 1, b= 1, c= 1, d= 1, e= 1, f= 1, g= 1|
                var z0= Mix(BPF.ar(LFSaw.ar([a, b]), a+b, e, amp));
                var z1= SinOsc.ar(a, Ringz.ar(z0, c.abs, f, 2pi), amp);
                var z2= SinOsc.ar(b, Ringz.ar(z0, d.abs, g, 2pi), amp);
                Out.ar(0, Pan2.ar(z0, 0, 0.3)+Pan2.ar(z1, -0.3, 0.3)+Pan2.ar(z2, 0.3, 0.3));
        }).play(s);
        s.sync;
        w= Window("sunday drawings2", Rect(128, 64, width, height), false);
        drawFunc= {
                var x, y;
                if(i==0, {
                        "//---------------------".postln;
                        [
                                \a, a, \b, b, \c, c, \d, d, \e, e, \f, f, \g, g
                        ].pairsDo{|m, n| (""++m++"="+n++";").postln};
                });
                if(i<fadeAtk, {
                        theta= theta+(d*e*f);
                        x= sin(theta*a%a/b*c*2pi);
                        y= sin(theta*b%b/a*d*2pi);
                        Pen.strokeColor= Color.grey(1, 0.5);
                        Pen.translate(width*0.5, height*0.5);
                        Pen.scale(f, g);
                        Pen.rotate(theta);
                        switch(a%3,
                                0, {Pen.strokeOval(Rect.aboutPoint(Point(x*100, y*100), a, b))},
                                1, {Pen.strokeRect(Rect.aboutPoint(Point(x*100, y*100), a, b))},
                                2, {Pen.line(Point(x*100, y*100), Point(a*c*100, b*d*100)); Pen.stroke}
                        );
                        syn.set(\amp, i/fadeAtk, \a, a, \b, b, \c, c, \d, d, \e, e, \f, f, \g, g);
                });
                if(i>(fadeAtk+fadeSus), {
                        clearFunc.value;
                        theta= 0;
                        Pen.fillColor= Color.grey(0, 5/fadeRel);
                        Pen.fillRect(Rect(0, 0, width, height));
                        syn.set(\amp, i.linexp(fadeAtk+fadeSus, fadeAtk+fadeSus+fadeRel, 1, 0.0001));
                });
                if(i==(fadeAtk+fadeSus+fadeRel), {
                        i= 0;
                }, {
                        i= i+1;
                });
        };
        clearFunc= {
               
                //--replace with preset from here
                a= 200.rand+1;
                b= 200.rand+1;
                c= 3.0.rand2;
                d= 3.0.rand2;
                e= 3.0.rand;
                f= 0.1.rrand(1.5)*#[1, -1].choose;
                g= 0.1.rrand(1.5)*#[1, -1].choose;
                //--to here
               
        };
        clearFunc.value;
        u= UserView(w, Rect(0, 0, width, height))
                .clearOnRefresh_(false)
                .drawFunc_(drawFunc)
                .background_(Color.black);
        w.front;
        u.animate= true;
        CmdPeriod.doOnce({if(w.isClosed.not, {w.close})});
        w.onClose= {syn.free};
};
)

sc140 - the sctweets album

i'm proud to have contributed with one short track on the just released CC BY-NC-SA 3 licensed album sc140. download/listen here. it is compiled by dan stowell and consists of 22 tracks with corresponding supercollider source code. the thing with this project is that all the tracks are written to fit within the twitter limitation of 140 characters. read the source code here

reference: 140 character examples

thewire.co.uk/articles/3177/

Pages

Subscribe to RSS - supercollider