Audiovisuals with SC - Example08b - faster is slower

See /f0blog/audiovisuals-with-sc/

//Example08b - faster is slower
//only one line differs from Example08a.  the one in the main loop where we invert the mapping.
(
s.latency= 0.05;
s.waitForBoot{

  //--window setup
  var width= 640, height= 480;
  var w= Window("Example08b - faster is slower", Rect(99, 99, width, height), false);
  var u= UserView(w, Rect(0, 0, width, height));

  //--variables
  var pat= Pn(Pshuf(#[0, 0, 0, 0, 0.1, 0.25, 0.5, 0.75, 1, 1], 8), inf).asStream;
  var syn= SynthDef(\av, {|rate= 1|
    var x= Decay2.kr(Impulse.kr(rate), 0.01, 0.1, 2, 0.2);
    var z= LPF.ar(LFSaw.ar(#[300, 301, 80, 81]).mean, 2000, x);
    Out.ar(0, Pan2.ar(z));
  }, #[0.05]).play(s);  //short lag time to avoid clipping
  var posx= 0;
  var fre= 0;
  var frameCount= 0;

  //--interface
  ~radius= 100;
  ~fps= 60;
  ~spreadx= 100;

  //--main loop
  u.drawFunc= {
    if(frameCount%~fps==0, {  //pick a new frequency only once per second
      fre= pat.next;  //get the next value from the stream
      syn.set(\rate, 1-fre*4+1);  //send to the synth
    });
    posx= sin(frameCount*(fre+1)%50/50*2pi);
    Pen.translate(width*0.5, height*0.5);  //offset drawing to the centre
    Pen.fillColor= Color.white;  //always fill with white color
    Pen.fillOval(Rect.aboutPoint(Point(posx*~spreadx, 0), ~radius, ~radius));
    frameCount= frameCount+1;
  };

  //--window management
  u.clearOnRefresh= true;
  u.background= Color.black;
  w.onClose= {syn.free};
  w.front;
  CmdPeriod.doOnce({w.close});
  Routine({
    var nextTime;
    while({w.isClosed.not}, {
      nextTime= Main.elapsedTime+(1/~fps);
      u.refresh;
      (nextTime-Main.elapsedTime).max(0.001).wait;
    });
  }).play(AppClock);
};
)

//change these while the program is running
~radius= 200;
~radius= 50;
~spreadx= 250;
~radius= 15;
~spreadx= 40;

//close the window to stop or press cmd+.